Index: Modules/FindwxWidgets.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Modules/FindwxWidgets.cmake,v
retrieving revision 1.2
diff -u -r1.2 FindwxWidgets.cmake
--- Modules/FindwxWidgets.cmake	27 Aug 2004 02:52:53 -0000	1.2
+++ Modules/FindwxWidgets.cmake	4 Jul 2006 17:22:15 -0000
@@ -1 +1,579 @@
-INCLUDE(FindwxWindows)
+# - Find a wxWidgets (a.k.a., wxWindows) installation.
+# This module finds if wxWidgets is installed and selects a default
+# configuration to use.
+#
+# The following variables are searched for and set to defaults in case
+# of multiple choices. Change them if the defaults are not desired:
+#
+#  WXWIDGETS_ROOT_DIR      - Base wxWidgets directory
+#                            (e.g., C:/wxWidgets-2.6.3).
+#  WXWIDGETS_LIB_DIR       - Path to wxWidgets libraries
+#                            (e.g., C:/wxWidgets-2.6.3/lib/vc_lib).
+#  WXWIDGETS_CONFIGURATION - Configuration to use
+#                            (e.g., msw, mswd, mswu, mswunivud, etc.)
+#  WXWIDGETS_USE_LIBS      - Libraries to use besides the common
+#                            required ones; set to base and core by
+#                            default.
+#
+#
+# The following are set after configuration is done:
+#
+#  WXWIDGETS_FOUND            - Set to TRUE if wxWidgets was found.
+#  WXWIDGETS_INCLUDE_DIR      - Include directories for WIN32 
+#                               i.e., where to find "wx/wx.h" and
+#                               "wx/setup.h"; possibly empty for unices.
+#  WXWIDGETS_LIBRARIES        - Path to the wxWidgets libraries.
+#  WXWIDGETS_LINK_DIRECTORIES - Link dirs, useful for rpath on UNIX.
+#                               Typically an empty string in WIN32 environment.
+#  WXWIDGETS_DEFINITIONS      - Contains defines required to compile/link 
+#                               against WX, e.g. -DWXUSINGDLL 
+#  WXWIDGETS_CXX_FLAGS        - Include dirs and ompiler flags for
+#                               unices, empty on WIN32. Esentially
+#                               "`wx-config --cxxflags`".
+#
+# Sample usage:
+#
+#   SET(WXWIDGETS_USE_LIBS base core gl net)
+#   FIND_PACKAGE(wxWidgets)
+#   IF(WXWIDGETS_FOUND)
+#     MESSAGE(STATUS "Found wxWidgets!")
+#     IF   (WXWIDGETS_INCLUDE_DIR)
+#       INCLUDE_DIRECTORIES(${WXWIDGETS_INCLUDE_DIR})
+#     ENDIF(WXWIDGETS_INCLUDE_DIR)
+#     IF   (WXWIDGETS_LINK_DIRECTORIES)
+#       LINK_DIRECTORIES(${WXWIDGETS_LINK_DIRECTORIES})
+#     ENDIF(WXWIDGETS_LINK_DIRECTORIES)
+#     IF   (WXWIDGETS_CXX_FLAGS)
+#       SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WXWIDGETS_CXX_FLAGS}")
+#     ENDIF(WXWIDGETS_CXX_FLAGS)
+#     IF   (WXWIDGETS_DEFINITIONS)
+#       ADD_DEFINITIONS(${WXWIDGETS_DEFINITIONS})
+#     ENDIF(WXWIDGETS_DEFINITIONS)
+#     # and for each of your dependant executable/library targets:
+#     TARGET_LINK_LIBRARIES(target ${WXWIDGETS_LIBRARIES})
+#   ENDIF(WXWIDGETS_FOUND)
+# 
+# Sample usage with monolithic wx build:
+#   SET(WXWIDGETS_USE_LIBS msw26 expat jpeg gl png regex tiff zlib)
+#   ...
+#
+# NOTES
+#   See UsewxWidgets.cmake for a convenience interface
+#
+#   This module has been tested on the WIN32 platform with wxWidgets
+#   2.6.2, 2.6.3, and 2.5.3. However, it has been designed to easily extend
+#   support to all possible builds, e.g., static/shared, debug/release,
+#   unicode, universal, multilib/monolithic, etc..
+#
+#   If you want to use the module and your build type is not supported
+#   out-of-the-box, please contact me to exchange information on how
+#   your system is setup and I'll try to add support for it.
+#
+# AUTHOR
+#   Miguel A. Figueroa-Villanueva (miguelf at ieee dot org).
+#   Jan Woetzel (jw at mip.informatik.uni-kiel.de).
+#
+#   Based on previous works of:
+#   Jan Woetzel (FindwxWindows.cmake), and Jorgen Bodde (FindwxWin.cmake).
+
+#
+# TODO/wish list (Jan Woetzel)
+#
+# (1) Option/Setting to use all available wx libs
+# In contrast to expert developer who lists the
+# minimal set of required libs in WXWIDGETS_USE_LIBS
+# there is the newbie user:
+#   - who just wants to link against WX with more 'magic'
+#   - doesn't know the internal structure of WX or how it was built,
+#     in particular if it is monolithic or not
+#   - want to link against all available WX libs
+# Basically, the intent here is to mimic what wx-config would do by
+# default (i.e., `wx-config --libs`).
+#
+# Possible solution:
+#   Add a reserved keyword "std" that initializes to what wx-config
+# would default to. If the user has not set the WXWIDGETS_USE_LIBS,
+# default to "std" instead of "base core" as it is now. To implement
+# "std" will basically boil down to a FOR_EACH lib-FOUND, but maybe
+# checking whether a minimal set was found.
+#
+
+#
+# Helper macro to control the debugging output globally.
+# - NOTE: This and all the DBG_MSG calls should be removed after the
+#         module stabilizes.
+#
+MACRO(DBG_MSG _MSG)
+#   MESSAGE(STATUS "${CMAKE_CURRENT_LIST_FILE}(${CMAKE_CURRENT_LIST_LINE}): ${_MSG}")
+ENDMACRO(DBG_MSG)
+
+#
+# Clear return values in case the module is loaded more than once.
+#
+SET(WXWIDGETS_FOUND FALSE)
+#
+SET(WXWIDGETS_INCLUDE_DIR      "")
+SET(WXWIDGETS_LIBRARIES        "")
+SET(WXWIDGETS_LINK_DIRECTORIES "")
+SET(WXWIDGETS_CXX_FLAGS        "")
+
+#=====================================================================
+#=====================================================================
+IF(WIN32)
+  SET(WIN32_STYLE_FIND 1)
+ENDIF(WIN32)
+IF(MINGW)
+  SET(WIN32_STYLE_FIND 0)
+  SET(UNIX_STYLE_FIND 1)
+ENDIF(MINGW)
+IF(UNIX)
+  SET(UNIX_STYLE_FIND 1)
+ENDIF(UNIX)
+
+
+IF(WIN32_STYLE_FIND)
+
+  #---------------------------------------------------------------------
+  # WIN32: Helper MACROS
+  #---------------------------------------------------------------------
+  # Get filename components for a configuration. For example,
+  #   if _CONFIGURATION = mswunivud, then _UNV=univ, _UCD=u _DBG=d
+  #   if _CONFIGURATION = mswu,      then _UNV="",   _UCD=u _DBG=""
+  #
+  MACRO(WX_GET_NAME_COMPONENTS _CONFIGURATION _UNV _UCD _DBG)
+    STRING(REGEX MATCH "univ" ${_UNV} "${_CONFIGURATION}")
+    STRING(REGEX REPLACE "msw.*(u)[d]*$" "u" ${_UCD} "${_CONFIGURATION}")
+    IF(${_UCD} STREQUAL ${_CONFIGURATION})
+      SET(${_UCD} "")
+    ENDIF(${_UCD} STREQUAL ${_CONFIGURATION})
+    STRING(REGEX MATCH "d$" ${_DBG} "${_CONFIGURATION}")
+  ENDMACRO(WX_GET_NAME_COMPONENTS)
+
+  #
+  # Find libraries associated to a configuration.
+  #
+  MACRO(WX_FIND_LIBS _UNV _UCD _DBG)
+    DBG_MSG("m_unv = ${_UNV}")
+    DBG_MSG("m_ucd = ${_UCD}")
+    DBG_MSG("m_dbg = ${_DBG}")
+
+    # Find wxWidgets common libraries
+    FOREACH(LIB png tiff jpeg zlib regex expat)
+      FIND_LIBRARY(WX_${LIB}${_DBG}
+        NAMES
+          wx${LIB}${_UCD}${_DBG} # for regex
+          wx${LIB}${_DBG}
+        PATHS ${WX_LIB_DIR}
+        NO_DEFAULT_PATH
+        )
+      MARK_AS_ADVANCED(WX_${LIB}${_DBG})
+    ENDFOREACH(LIB)
+
+    # Find wxWidgets multilib base libraries
+    FIND_LIBRARY(WX_base${_DBG}
+      NAMES
+        wxbase26${_UCD}${_DBG}
+        wxbase25${_UCD}${_DBG}
+      PATHS ${WX_LIB_DIR}
+      NO_DEFAULT_PATH
+      )
+    MARK_AS_ADVANCED(WX_base${_DBG})
+    FOREACH(LIB net odbc xml)
+      FIND_LIBRARY(WX_${LIB}${_DBG}
+        NAMES
+          wxbase26${_UCD}${_DBG}_${LIB}
+          wxbase25${_UCD}${_DBG}_${LIB}
+        PATHS ${WX_LIB_DIR}
+        NO_DEFAULT_PATH
+        )
+      MARK_AS_ADVANCED(WX_${LIB}${_DBG})
+    ENDFOREACH(LIB)
+
+    # Find wxWidgets monolithic library
+    FIND_LIBRARY(WX_mono${_DBG}
+      NAMES
+        wxmsw${_UNV}26${_UCD}${_DBG}
+        wxmsw${_UNV}25${_UCD}${_DBG}
+      PATHS ${WX_LIB_DIR}
+      NO_DEFAULT_PATH
+      )
+    MARK_AS_ADVANCED(WX_mono${_DBG})
+
+    # Find wxWidgets multilib libraries
+    FOREACH(LIB core adv html media xrc dbgrid gl qa)
+      FIND_LIBRARY(WX_${LIB}${_DBG}
+        NAMES
+          wxmsw${_UNV}26${_UCD}${_DBG}_${LIB}
+          wxmsw${_UNV}25${_UCD}${_DBG}_${LIB}
+        PATHS ${WX_LIB_DIR}
+        NO_DEFAULT_PATH
+        )
+      MARK_AS_ADVANCED(WX_${LIB}${_DBG})
+    ENDFOREACH(LIB)
+  ENDMACRO(WX_FIND_LIBS)
+
+  #
+  # Clear all library paths, so that FIND_LIBRARY refinds them.
+  #
+  # Clear a lib, reset its found flag, and mark as advanced.
+  MACRO(WX_CLEAR_LIB _LIB)
+    SET(${_LIB} "${_LIB}-NOTFOUND" CACHE FILEPATH "Cleared." FORCE)
+    SET(${_LIB}_FOUND FALSE)    
+    MARK_AS_ADVANCED(${_LIB})
+  ENDMACRO(WX_CLEAR_LIB)
+  # Clear all debug or release library paths (arguments are "d" or "").
+  MACRO(WX_CLEAR_ALL_LIBS _DBG)
+    # Clear wxWidgets common libraries
+    FOREACH(LIB png tiff jpeg zlib regex expat)
+      WX_CLEAR_LIB(WX_${LIB}${_DBG})
+    ENDFOREACH(LIB)
+
+    # Clear wxWidgets multilib base libraries
+    WX_CLEAR_LIB(WX_base${_DBG})
+    FOREACH(LIB net odbc xml)
+      WX_CLEAR_LIB(WX_${LIB}${_DBG})
+    ENDFOREACH(LIB)
+
+    # Clear wxWidgets monolithic library
+    WX_CLEAR_LIB(WX_mono${_DBG})
+
+    # Clear wxWidgets multilib libraries
+    FOREACH(LIB core adv html media xrc dbgrid gl qa)
+      WX_CLEAR_LIB(WX_${LIB}${_DBG})
+    ENDFOREACH(LIB)
+  ENDMACRO(WX_CLEAR_ALL_LIBS)
+  # Clear all wxWidgets debug libraries.
+  MACRO(WX_CLEAR_ALL_DBG_LIBS)
+    WX_CLEAR_ALL_LIBS("d")
+  ENDMACRO(WX_CLEAR_ALL_DBG_LIBS)
+  # Clear all wxWidgets release libraries.
+  MACRO(WX_CLEAR_ALL_REL_LIBS)
+    WX_CLEAR_ALL_LIBS("")
+  ENDMACRO(WX_CLEAR_ALL_REL_LIBS)
+
+  #
+  # Set the WXWIDGETS_LIBRARIES variable.
+  # Also, Sets output variable WXWIDGETS_FOUND to FALSE if it fails.
+  #
+  MACRO(WX_SET_LIBRARIES _LIBS _DBG)
+    IF(WX_USE_REL_AND_DBG)
+      DBG_MSG("looking for ${${_LIBS}}")
+      FOREACH(LIB ${${_LIBS}})
+        DBG_MSG("Finding ${LIB} and ${LIB}d")
+        DBG_MSG("WX_${LIB}  : ${WX_${LIB}}")
+        DBG_MSG("WX_${LIB}d : ${WX_${LIB}d}")
+        IF(WX_${LIB} AND WX_${LIB}d)
+          DBG_MSG("Found ${LIB} and ${LIB}d")
+          SET(WXWIDGETS_LIBRARIES ${WXWIDGETS_LIBRARIES}
+            debug     ${WX_${LIB}d}
+            optimized ${WX_${LIB}}
+            )
+        ELSE(WX_${LIB} AND WX_${LIB}d)
+          DBG_MSG("- not found due to missing WX_${LIB}=${WX_${LIB}} or WX_${LIB}d=${WX_${LIB}d}")
+          SET(WXWIDGETS_FOUND FALSE)
+        ENDIF(WX_${LIB} AND WX_${LIB}d)
+      ENDFOREACH(LIB)
+    ELSE(WX_USE_REL_AND_DBG)
+      FOREACH(LIB ${${_LIBS}})
+        DBG_MSG("Finding ${LIB}${_DBG}")
+        DBG_MSG("WX_${LIB}${_DBG} : ${WX_${LIB}${_DBG}}")
+        IF(WX_${LIB}${_DBG})
+          DBG_MSG("Found ${LIB}${_DBG}")
+          SET(WXWIDGETS_LIBRARIES ${WXWIDGETS_LIBRARIES}
+            ${WX_${LIB}${_DBG}}
+            )
+        ELSE(WX_${LIB}${_DBG})
+          DBG_MSG("- not found due to missing WX_${LIB}${_DBG}=${WX_${LIB}${_DBG}}")
+          SET(WXWIDGETS_FOUND FALSE)
+        ENDIF(WX_${LIB}${_DBG})
+      ENDFOREACH(LIB)
+    ENDIF(WX_USE_REL_AND_DBG)
+
+    FOREACH(LIB ${${_LIBS}})
+      DBG_MSG("required: ${LIB}")
+      IF(LIB STREQUAL "gl")
+        DBG_MSG("gl required: ${LIB}")
+        SET(WXWIDGETS_LIBRARIES ${WXWIDGETS_LIBRARIES}
+          opengl32
+          glu32
+          )
+      ENDIF(LIB STREQUAL "gl")
+    ENDFOREACH(LIB ${${_LIBS}})
+
+    SET(WXWIDGETS_LIBRARIES ${WXWIDGETS_LIBRARIES}
+      winmm
+      comctl32
+      rpcrt4
+      wsock32
+      )
+  ENDMACRO(WX_SET_LIBRARIES)
+
+  #---------------------------------------------------------------------
+  # WIN32: Start actual work.
+  #---------------------------------------------------------------------
+  #
+  # Look for an installation tree.
+  #
+  FIND_PATH(WXWIDGETS_ROOT_DIR include/wx/wx.h
+    $ENV{WXWIN}
+    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\wxWidgets_is1;Inno Setup: App Path]"  ## WX 2.6.x
+    C:/wxWidgets-2.6.3
+    D:/wxWidgets-2.6.3
+    C:/wxWidgets-2.6.2
+    D:/wxWidgets-2.6.2
+    C:/wxWidgets-2.6.1
+    D:/wxWidgets-2.6.1
+    C:/wxWidgets-2.6.0
+    D:/wxWidgets-2.6.0
+    C:/wxWidgets-2.5.5
+    D:/wxWidgets-2.5.5
+    C:/wxWidgets-2.5.4
+    D:/wxWidgets-2.5.4
+    C:/wxWidgets-2.5.3
+    D:/wxWidgets-2.5.3
+    C:/wxWidgets-2.5.2
+    D:/wxWidgets-2.5.2
+    C:/wxWidgets-2.5.1
+    D:/wxWidgets-2.5.1
+    DOC "wxWidgets base/installation directory?"
+    )
+
+  # If WXWIDGETS_ROOT_DIR changed, clear all libraries and lib dir.
+  IF(NOT WX_ROOT_DIR STREQUAL WXWIDGETS_ROOT_DIR)
+    SET(WX_ROOT_DIR ${WXWIDGETS_ROOT_DIR} CACHE INTERNAL "WXWIDGETS_ROOT_DIR")
+    #  WX_CLEAR_ALL_DBG_LIBS()
+    #  WX_CLEAR_ALL_REL_LIBS()
+    SET(WXWIDGETS_LIB_DIR "WXWIDGETS_LIB_DIR-NOTFOUND" CACHE PATH "Cleared." FORCE)
+  ENDIF(NOT WX_ROOT_DIR STREQUAL WXWIDGETS_ROOT_DIR)
+
+  IF(WX_ROOT_DIR)
+
+    # *** Temporary hack for cmake 2.2-patch3 and older.
+    #     FIND_PATH(<VAR> NAMES ... PATHS ...) not available
+    # ***
+    # JW: select one default tree inside the already determined wx tree
+    # prefer static/shared order usually consistent with build settings
+    IF(BUILD_SHARED_LIBS)
+      FIND_PATH(WXWIDGETS_LIB_DIR
+        NAMES wxpng.lib wxpngd.lib
+        PATHS
+        ${WX_ROOT_DIR}/lib/vc_dll   # prefer shared
+        ${WX_ROOT_DIR}/lib/vc_lib
+        DOC "Path to wxWidgets libraries?"
+        NO_DEFAULT_PATH
+        )
+    ELSE(BUILD_SHARED_LIBS)
+      FIND_PATH(WXWIDGETS_LIB_DIR
+        NAMES wxpng.lib wxpngd.lib
+        PATHS
+        ${WX_ROOT_DIR}/lib/vc_lib   # prefer static
+        ${WX_ROOT_DIR}/lib/vc_dll
+        DOC "Path to wxWidgets libraries?"
+        NO_DEFAULT_PATH
+        )
+    ENDIF(BUILD_SHARED_LIBS)
+
+    # If WXWIDGETS_LIB_DIR changed, clear all libraries.
+    IF(NOT WX_LIB_DIR STREQUAL WXWIDGETS_LIB_DIR)
+      SET(WX_LIB_DIR ${WXWIDGETS_LIB_DIR} CACHE INTERNAL "WXWIDGETS_LIB_DIR")
+      WX_CLEAR_ALL_DBG_LIBS()
+      WX_CLEAR_ALL_REL_LIBS()
+    ENDIF(NOT WX_LIB_DIR STREQUAL WXWIDGETS_LIB_DIR)
+
+    IF(WX_LIB_DIR)
+      SET(WXWIDGETS_FOUND TRUE)
+      
+      IF(WX_LIB_DIR MATCHES ".*[dD][lL][lL].*")
+        DBG_MSG("detected SHARED/DLL tree WX_LIB_DIR=${WX_LIB_DIR}")
+        # add define for correct dllimport to link against WX DLL
+        SET(WXWIDGETS_DEFINITIONS "-DWXUSINGDLL")
+      ENDIF(WX_LIB_DIR MATCHES ".*[dD][lL][lL].*")
+      
+      #---------------------------------------------------------------------
+      # WIN32: ???
+      #---------------------------------------------------------------------
+      # Search for possible configuration type availabilities
+      # ***** SET(WX_LAST_CFG "")
+      FOREACH(CFG mswunivud mswunivd mswud mswd mswunivu mswuniv mswu msw)
+        SET(WX_${CFG}_FOUND FALSE)
+        IF(EXISTS ${WX_LIB_DIR}/${CFG})
+          SET(WX_CONFIGURATION_LIST ${WX_CONFIGURATION_LIST} ${CFG})
+          SET(WX_${CFG}_FOUND TRUE)
+          SET(WX_CONFIGURATION ${CFG})
+        ENDIF(EXISTS ${WX_LIB_DIR}/${CFG})
+      ENDFOREACH(CFG)
+
+      # ***** SET(WX_USE_REL_AND_DBG FALSE)
+      IF(WX_CONFIGURATION)
+        # if selected configuration wasn't found, force the default one
+        # else, use it but still force a refresh for the list in doc string
+        IF(NOT WX_${WXWIDGETS_CONFIGURATION}_FOUND)
+          SET(WXWIDGETS_CONFIGURATION ${WX_CONFIGURATION} CACHE STRING
+            "Set wxWidgets configuration (${WX_CONFIGURATION_LIST})" FORCE)
+        ELSE(NOT WX_${WXWIDGETS_CONFIGURATION}_FOUND)
+          SET(WXWIDGETS_CONFIGURATION ${WXWIDGETS_CONFIGURATION} CACHE STRING
+            "Set wxWidgets configuration (${WX_CONFIGURATION_LIST})" FORCE)
+        ENDIF(NOT WX_${WXWIDGETS_CONFIGURATION}_FOUND)
+
+        # if release config was selected, and both release/debug exist
+        IF(WX_${WXWIDGETS_CONFIGURATION}d_FOUND)
+          OPTION(WXWIDGETS_USE_REL_AND_DBG
+            "Use release and debug configurations?" TRUE)
+          SET(WX_USE_REL_AND_DBG ${WXWIDGETS_USE_REL_AND_DBG})
+        ELSE(WX_${WXWIDGETS_CONFIGURATION}d_FOUND)
+          # if the option exists, force it to false
+          IF(WXWIDGETS_USE_REL_AND_DBG)
+            SET(WXWIDGETS_USE_REL_AND_DBG FALSE CACHE BOOL
+              "No ${WXWIDGETS_CONFIGURATION}d found." FORCE)
+          ENDIF(WXWIDGETS_USE_REL_AND_DBG)
+          SET(WX_USE_REL_AND_DBG FALSE)
+        ENDIF(WX_${WXWIDGETS_CONFIGURATION}d_FOUND)
+
+        # Get configuration parameters from the name.
+        WX_GET_NAME_COMPONENTS(${WXWIDGETS_CONFIGURATION} UNV UCD DBG)
+
+        # Set wxWidgets main include directory.
+        IF(EXISTS ${WX_ROOT_DIR}/include/wx/wx.h)
+          SET(WXWIDGETS_INCLUDE_DIR ${WX_ROOT_DIR}/include)
+        ELSE(EXISTS ${WX_ROOT_DIR}/include/wx/wx.h)
+          DBG_MSG("WXWIDGET_FOUND FALSE because WX_ROOT_DIR=${WX_ROOT_DIR} has no ${WX_ROOT_DIR}/include/wx/wx.h")
+          SET(WXWIDGETS_FOUND FALSE)
+        ENDIF(EXISTS ${WX_ROOT_DIR}/include/wx/wx.h)
+
+        # Set wxWidgets lib setup include directory.
+        IF(EXISTS ${WX_LIB_DIR}/${WXWIDGETS_CONFIGURATION}/wx/setup.h)
+          SET(WXWIDGETS_INCLUDE_DIR ${WXWIDGETS_INCLUDE_DIR}
+            ${WX_LIB_DIR}/${WXWIDGETS_CONFIGURATION})
+        ELSE(EXISTS ${WX_LIB_DIR}/${WXWIDGETS_CONFIGURATION}/wx/setup.h)
+          DBG_MSG("WXWIDGET_FOUND FALSE because  ${WX_LIB_DIR}/${WXWIDGETS_CONFIGURATION}/wx/setup.h does not exists.")
+          SET(WXWIDGETS_FOUND FALSE)
+        ENDIF(EXISTS ${WX_LIB_DIR}/${WXWIDGETS_CONFIGURATION}/wx/setup.h)
+        #FIND_PATH(WX_SETUP_INCLUDE_DIR wx/setup.h
+          #          ${WX_LIB_DIR}/${WXWIDGETS_CONFIGURATION})
+        #MARK_AS_ADVANCED(WX_SETUP_INCLUDE_DIR)
+
+        # Find wxWidgets libraries.
+        WX_FIND_LIBS("${UNV}" "${UCD}" "${DBG}")
+        IF(WX_USE_REL_AND_DBG)
+          WX_FIND_LIBS("${UNV}" "${UCD}" "d")
+        ENDIF(WX_USE_REL_AND_DBG)
+
+        # Libraries we are interested in.
+        IF(WXWIDGETS_USE_LIBS)
+          # Add the common required libs.
+          SET(WXWIDGETS_USE_LIBS ${WXWIDGETS_USE_LIBS}
+            png tiff jpeg zlib regex expat
+            )
+        ELSE(WXWIDGETS_USE_LIBS)
+          # Default minimal use setting (i.e., link to only core and base).
+          SET(WXWIDGETS_USE_LIBS base core
+            png tiff jpeg zlib regex expat
+            )
+        ENDIF(WXWIDGETS_USE_LIBS)
+
+        # Settings for requested libs (i.e., include dir, libraries, etc.).
+        WX_SET_LIBRARIES(WXWIDGETS_USE_LIBS "${DBG}")
+
+      ENDIF(WX_CONFIGURATION)
+    ENDIF(WX_LIB_DIR)
+  ENDIF(WX_ROOT_DIR)
+
+
+  #=====================================================================
+  #=====================================================================
+ELSE(WIN32_STYLE_FIND)
+  IF(UNIX_STYLE_FIND)
+
+    FIND_PROGRAM(WXWIDGETS_CONFIG_EXE wx-config)
+    IF(WXWIDGETS_CONFIG_EXE)
+      SET(WXWIDGETS_FOUND TRUE)
+
+      # run the wx-config program to get cxxflags
+      EXEC_PROGRAM(${WXWIDGETS_CONFIG_EXE}
+        ARGS "--cxxflags"
+        OUTPUT_VARIABLE WXWIDGETS_CXX_FLAGS
+        RETURN_VALUE RET)
+      IF(RET EQUAL 0)
+        # parse definitions from cxxflags
+        STRING(REGEX MATCHALL "-D.*[^ ;]+" WXWIDGETS_DEFINITIONS  ${WXWIDGETS_CXX_FLAGS})
+        DBG_MSG("\nWXWIDGETS_DEFINITIONS=${WXWIDGETS_DEFINITIONS}")
+        # drop -D* from CXXFLAGS
+        STRING(REGEX REPLACE "-D[^ ;]*" ""  WXWIDGETS_CXX_FLAGS  ${WXWIDGETS_CXX_FLAGS})
+
+        # parse incdirs from cxxflags, drop -I prefix
+        STRING(REGEX MATCHALL "-I.*[^ ;]+" WXWIDGETS_INCLUDE_DIR  ${WXWIDGETS_CXX_FLAGS})
+        STRING(REGEX REPLACE "-I" ""  WXWIDGETS_INCLUDE_DIR "${WXWIDGETS_INCLUDE_DIR}")
+        # convert space to semicolons for list
+        SEPARATE_ARGUMENTS( WXWIDGETS_INCLUDE_DIR )
+
+        # drop -I* from CXXFLAGS - postponed until -isystem is available to INCLUDE_DIRECTORIES to avoid pedantic warnings
+        #STRING(REGEX REPLACE "-I[^ ;]*" ""  WXWIDGETS_CXX_FLAGS  ${WXWIDGETS_CXX_FLAGS})
+	
+	IF   (CMAKE_CXX_COMPILER MATCHES g\\+\\+)
+          # handle WX include dirs as system directories - ignores pedantic warnings with gcc
+          # replace -I by -isystem
+          STRING(REGEX REPLACE "-I" "-isystem" WXWIDGETS_CXX_FLAGS  ${WXWIDGETS_CXX_FLAGS})
+	ENDIF(CMAKE_CXX_COMPILER MATCHES g\\+\\+)
+	
+      ELSE(RET EQUAL 0)
+        DBG_MSG("${WXWIDGETS_CONFIG_EXE} --cxxflags FAILED with RET=${RET}")
+        SET(WXWIDGETS_FOUND FALSE)
+      ENDIF(RET EQUAL 0)
+      
+      
+      # run the wx-config program to get the libs
+      # - NOTE: wx-config doesn't verify that the libs requested exist
+      #         it just produces the names. Maybe a TRY_COMPILE would
+      #         be useful here...
+      #STRING(REPLACE ";" "," WXWIDGETS_USE_LIBS "${WXWIDGETS_USE_LIBS}")
+      STRING(REGEX REPLACE ";" "," WXWIDGETS_USE_LIBS "${WXWIDGETS_USE_LIBS}")
+      EXEC_PROGRAM(${WXWIDGETS_CONFIG_EXE}
+        ARGS "--libs ${WXWIDGETS_USE_LIBS}"
+        OUTPUT_VARIABLE WXWIDGETS_LIBRARIES
+        RETURN_VALUE RET)
+      IF(RET EQUAL 0)
+        SEPARATE_ARGUMENTS(WXWIDGETS_LIBRARIES)
+        STRING(REGEX REPLACE "-framework;" "-framework "
+          WXWIDGETS_LIBRARIES
+          "${WXWIDGETS_LIBRARIES}")
+
+        # extract linkdirs (-L) for rpath (i.e., LINK_DIRECTORIES)
+        STRING(REGEX MATCHALL "-L[^ ;]+"
+          WXWIDGETS_LINK_DIRECTORIES
+          "${WXWIDGETS_LIBRARIES}")
+        STRING(REGEX REPLACE "-L" ""
+          WXWIDGETS_LINK_DIRECTORIES "${WXWIDGETS_LINK_DIRECTORIES}")
+
+        # convert space to semicolons for list
+        SEPARATE_ARGUMENTS( WXWIDGETS_LINK_DIRECTORIES )
+      ELSE(RET EQUAL 0)
+        SET(WXWIDGETS_FOUND FALSE)
+      ENDIF(RET EQUAL 0)
+    ENDIF(WXWIDGETS_CONFIG_EXE)
+    
+  ELSE(UNIX_STYLE_FIND)
+    IF(NOT wxWidgets_FIND_QUIETLY)
+      MESSAGE(STATUS "${CMAKE_CURRENT_LIST_FILE}(${CMAKE_CURRENT_LIST_LINE}): \n"
+                     "  Platform unknown/unsupported. It's neither WIN32 nor UNIX style find.")
+    ENDIF(NOT wxWidgets_FIND_QUIETLY)
+  ENDIF(UNIX_STYLE_FIND)
+ENDIF(WIN32_STYLE_FIND)
+
+DBG_MSG("WXWIDGETS_FOUND      : ${WXWIDGETS_FOUND}"      )
+DBG_MSG("WXWIDGETS_INCLUDE_DIR: ${WXWIDGETS_INCLUDE_DIR}")
+DBG_MSG("WXWIDGETS_LINK_DIRECTORIES: ${WXWIDGETS_LINK_DIRECTORIES}")
+DBG_MSG("WXWIDGETS_CXX_FLAGS       : ${WXWIDGETS_CXX_FLAGS}"       )
+
+#=====================================================================
+#=====================================================================
+IF(NOT WXWIDGETS_FOUND)
+  # make FIND_PACKAGE friendly
+  IF(NOT wxWidgets_FIND_QUIETLY)
+    IF(wxWidgets_FIND_REQUIRED)
+      MESSAGE(FATAL_ERROR
+        "wxWidgets required, please specify it's location.")
+    ELSE(wxWidgets_FIND_REQUIRED)
+      MESSAGE(STATUS "ERROR: wxWidgets was not found.")
+    ENDIF(wxWidgets_FIND_REQUIRED)
+  ENDIF(NOT wxWidgets_FIND_QUIETLY)
+ENDIF(NOT WXWIDGETS_FOUND)
Index: Modules/FindwxWindows.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Modules/FindwxWindows.cmake,v
retrieving revision 1.18
diff -u -r1.18 FindwxWindows.cmake
--- Modules/FindwxWindows.cmake	12 Jan 2006 16:10:22 -0000	1.18
+++ Modules/FindwxWindows.cmake	4 Jul 2006 17:43:31 -0000
@@ -606,7 +606,11 @@
       ##MESSAGE("DBG: WX_CONFIG_ARGS_LIBS=${WX_CONFIG_ARGS_LIBS}===")
       
       # set CXXFLAGS to be fed into CMAKE_CXX_FLAGS by the user:
-      SET(CMAKE_WXWINDOWS_CXX_FLAGS "`${CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE} --cxxflags|sed -e s/-I/-isystem/g`")
+      IF (CMAKE_CXX_COMPILER MATCHES g\\+\\+)
+        SET(CMAKE_WXWINDOWS_CXX_FLAGS "`${CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE} --cxxflags|sed -e s/-I/-isystem/g`")
+      ELSE(CMAKE_CXX_COMPILER MATCHES g\\+\\+)
+        SET(CMAKE_WXWINDOWS_CXX_FLAGS "`${CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE} --cxxflags`")
+      ENDIF(CMAKE_CXX_COMPILER MATCHES g\\+\\+)
       ##MESSAGE("DBG: for compilation:
         ##CMAKE_WXWINDOWS_CXX_FLAGS=${CMAKE_WXWINDOWS_CXX_FLAGS}===")
 
Index: Modules/UsewxWidgets.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Modules/UsewxWidgets.cmake,v
retrieving revision 1.3
diff -u -r1.3 UsewxWidgets.cmake
--- Modules/UsewxWidgets.cmake	14 Dec 2005 18:51:08 -0000	1.3
+++ Modules/UsewxWidgets.cmake	4 Jul 2006 17:50:34 -0000
@@ -1,4 +1,116 @@
-# - Same as Use_wxWindows
+# - Convenience include for using wxWidgets library
+# Finds if wxWidgets is installed 
+# and set the appropriate libs, incdirs, flags etc. 
+# INCLUDE_DIRECTORIES, LINK_DIRECTORIES and ADD_DEFINITIONS
+# are called.
 #
+# USAGE
+# Include this file inside your CMakeLists.txt:
+#   SET(WXWIDGETS_USE_GL 1) # optionally: set this is you need wxgl
+#   SET( WXWIDGETS_USE_LIBS xml xrc ) # optionally: more than wx std libs?
+#   INCLUDE (${CMAKE_ROOT}/Modules/UsewxWidgets.cmake )
+# 
+# AUTHOR
+#  Jan Woetzel <jw -at- mip.informatik.uni-kiel.de>
 
-INCLUDE(Use_wxWindows)
+
+# debug message and logging. 
+# comment these for distribution
+IF    (NOT LOGFILE )
+  #  SET(LOGFILE "${PROJECT_BINARY_DIR}/CMakeOutput.log")
+ENDIF (NOT LOGFILE )
+MACRO(MSG _MSG)
+  #  FILE(APPEND ${LOGFILE} "${CMAKE_CURRENT_LIST_FILE}(${CMAKE_CURRENT_LIST_LINE}):   ${_MSG}\n")
+  #  MESSAGE(STATUS "${CMAKE_CURRENT_LIST_FILE}(${CMAKE_CURRENT_LIST_LINE}): ${_MSG}")
+ENDMACRO(MSG)
+
+#
+# set wx libs we depend on. 
+# "std" libs is only supported by linux
+# emulate "std" behavior here.
+#
+IF   (WIN32)
+  # useful std wx libs 
+  # workaround until Find script supports std libs with wx msw  mono and multi build 
+  SET(WXWIDGETS_LIBS_STD
+    expat regex 
+    jpeg png tiff zlib  
+    # xml net adv media html odbc xrc
+    )
+  MSG("WXWIDGETS_LIBS_STD=${WXWIDGETS_LIBS_STD}")
+  
+  # use mono instead of multilib build?
+  OPTION(WXWIDGETS_USE_MONOLITHIC "use monolithic WX USE_LIBS etting  for build?" OFF)
+  #MARK_AS_ADVANCED(WXWIDGETS_USE_MONOLITHIC)
+  MSG("WXWIDGETS_USE_MONOLITHIC=${WXWIDGETS_USE_MONOLITHIC}")
+  
+  IF   (WXWIDGETS_USE_MONOLITHIC)
+    SET(WXWIDGETS_USE_LIBS ${WXWIDGETS_USE_LIBS}  
+      mono 
+      ${WXWIDGETS_LIBS_STD} )
+    MSG("selected MONOLITHIC WX")
+  ELSE (WXWIDGETS_USE_MONOLITHIC)
+    SET(WXWIDGETS_USE_LIBS ${WXWIDGETS_USE_LIBS}  
+      base core
+      ${WXWIDGETS_LIBS_STD} )
+    MSG("selected MULTILIB WX")
+  ENDIF(WXWIDGETS_USE_MONOLITHIC)
+ELSE (WIN32)
+  # use wx std libs
+  SET(WXWIDGETS_USE_LIBS ${WXWIDGETS_USE_LIBS} std)
+ENDIF(WIN32)
+
+# check WXWIDGETS and WXWINDOWS for backward compatibility 
+#OPTION(WXWIDGETS_USE_GL "use wxgl lib with wxWidgets?" OFF)
+IF   (WXWIDGETS_USE_GL OR WXWINDOWS_USE_GL)
+  SET(WXWIDGETS_USE_LIBS ${WXWIDGETS_USE_LIBS} gl)
+ENDIF(WXWIDGETS_USE_GL OR WXWINDOWS_USE_GL)
+
+
+#
+# start the find script with the above settings 
+#
+
+# INCLUDE(FindwxWidgets)
+FIND_PACKAGE(wxWidgets REQUIRED)
+
+
+#
+# add results
+#
+MSG("WXWIDGETS_FOUND=${WXWIDGETS_FOUND}")
+IF(   WXWIDGETS_FOUND)
+  IF   (WXWIDGETS_INCLUDE_DIR)
+    INCLUDE_DIRECTORIES( ${WXWIDGETS_INCLUDE_DIR} )
+    MSG("WXWIDGETS_INCLUDE_DIR=${WXWIDGETS_INCLUDE_DIR}")
+  ENDIF(WXWIDGETS_INCLUDE_DIR)
+
+  IF   (WXWIDGETS_LINK_DIRECTORIES)
+    LINK_DIRECTORIES(${WXWIDGETS_LINK_DIRECTORIES})
+    MSG("WXWIDGETS_LINK_DIRECTORIES=${WXWIDGETS_LINK_DIRECTORIES}")
+  ENDIF(WXWIDGETS_LINK_DIRECTORIES)
+
+  IF   (WXWIDGETS_CXX_FLAGS)
+    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WXWIDGETS_CXX_FLAGS}")
+    MSG("WXWIDGETS_CXX_FLAGS=${WXWIDGETS_CXX_FLAGS}")
+  ENDIF(WXWIDGETS_CXX_FLAGS)
+
+  IF   (WXWIDGETS_DEFINITIONS)
+    ADD_DEFINITIONS( ${WXWIDGETS_DEFINITIONS} )
+    MSG("WXWIDGETS_DEFINITIONS=${WXWIDGETS_DEFINITIONS}")
+  ENDIF(WXWIDGETS_DEFINITIONS)  
+
+  # just for backward compatibility: add deps to all targets
+  # library projects better use advanced FIND_PACKAGE(wxWidgets) directly.
+  IF(WXWIDGETS_LIBRARIES)
+    LINK_LIBRARIES(${WXWIDGETS_LIBRARIES})
+    # BUG: str too long:  MSG("WXWIDGETS_LIBRARIES=${WXWIDGETS_LIBRARIES}")
+    IF(LOGFILE)
+      FILE(APPEND ${LOGFILE} "${CMAKE_CURRENT_LIST_FILE}(${CMAKE_CURRENT_LIST_LINE}):   ${WXWIDGETS_LIBRARIES}\n")
+    ENDIF(LOGFILE)
+  ENDIF(WXWIDGETS_LIBRARIES)
+  
+  
+ELSE (WXWIDGETS_FOUND)
+  MESSAGE("wxWidgest requested but not found.")
+ENDIF(WXWIDGETS_FOUND) 
Index: Source/CMakeLists.txt
===================================================================
RCS file: /cvsroot/CMake/CMake/Source/CMakeLists.txt,v
retrieving revision 1.292
diff -u -r1.292 CMakeLists.txt
--- Source/CMakeLists.txt	4 May 2006 01:42:51 -0000	1.292
+++ Source/CMakeLists.txt	4 Jul 2006 18:12:13 -0000
@@ -324,11 +324,11 @@
 ENDIF(BUILD_MFCDialog)
 
 # WX Widgets GUI
-OPTION(CMAKE_BUILD_WX_DIALOG "Build wxWidgets dialog for CMake" FALSE)
-MARK_AS_ADVANCED(CMAKE_BUILD_WX_DIALOG)
-IF(CMAKE_BUILD_WX_DIALOG)
+OPTION(BUILD_WX_DIALOG "Build wxWidgets dialog for CMake" FALSE)
+MARK_AS_ADVANCED(BUILD_WX_DIALOG)
+IF(BUILD_WX_DIALOG)
   SUBDIRS(WXDialog)
-ENDIF(CMAKE_BUILD_WX_DIALOG)
+ENDIF(BUILD_WX_DIALOG)
 
 # Testing
 IF (NOT DART_ROOT)
@@ -1063,9 +1063,8 @@
     ENDIF(JAVA_COMPILE AND JAVA_RUNTIME AND JAVA_ARCHIVE AND NOT MINGW)
   ENDIF(NOT CMAKE_TEST_GENERATOR MATCHES "Xcode")
 
-
-  IF (CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE OR WXWINDOWS_INCLUDE_DIR)
-    # Will be set if the wxwindows gui is on
+  IF  (BUILD_WX_DIALOG OR CMAKE_WXWIDGETS_WXCONFIG_EXECUTABLE OR WXWIDGETS_INCLUDE_DIR)
+    # Will be set if the WX gui is on
     ADD_TEST(UseWX ${CMAKE_CTEST_COMMAND}
       --build-and-test
       "${CMake_SOURCE_DIR}/Tests/UseWX"
@@ -1073,11 +1072,11 @@
       --build-generator ${CMAKE_TEST_GENERATOR}
       --build-makeprogram ${CMAKE_TEST_MAKEPROGRAM}
       --build-exe-dir ${CMake_BINARY_DIR}/Tests/UseWX
-      --build-project UsewxWindows
-      --build-options -DCMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE:FILEPATH=${CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE}
+      --build-project UsewxWidgets
+      --build-options -DCMAKE_WXWIDGETS_WXCONFIG_EXECUTABLE:FILEPATH=${CMAKE_WXWIDGETS_WXCONFIG_EXECUTABLE}
       --test-command UseWX
       )
-  ENDIF (CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE OR WXWINDOWS_INCLUDE_DIR)
+  ENDIF(BUILD_WX_DIALOG OR CMAKE_WXWIDGETS_WXCONFIG_EXECUTABLE OR WXWIDGETS_INCLUDE_DIR)
 
   IF(UNIX)
     STRING(COMPARE EQUAL "${CMAKE_INSTALL_PREFIX}" "${CMake_BINARY_DIR}/Tests/TestShellInstall/Prefix"
Index: Source/WXDialog/CMakeLists.txt
===================================================================
RCS file: /cvsroot/CMake/CMake/Source/WXDialog/CMakeLists.txt,v
retrieving revision 1.23
diff -u -r1.23 CMakeLists.txt
--- Source/WXDialog/CMakeLists.txt	14 Jul 2005 21:21:24 -0000	1.23
+++ Source/WXDialog/CMakeLists.txt	4 Jul 2006 18:09:49 -0000
@@ -9,32 +9,15 @@
 ## License:     wxWidgets License
 ##---------------------------------------------------------------------------
 
+# wxWidows -> wxWidgets Jan Woetzel 07/2006
+# tested with wx 2.6.3 with "multilib" build on Windows XP
 
-#wxWidgets build related stuff
-SET(WXW_USE_DEBUG OFF)
-SET(WXW_USE_UNICODE OFF)
-SET(WXW_USE_SHARED OFF)
-SET(WXW_USE_UNIV OFF)
-SET(WXW_USE_MONO OFF)
-SET(WXW_FILE_VERSION "26")
-SET(WXW_VERSION "2.6")
-
-#CMake Options
+# CMake Options
 SET(CMAKE_VERBOSE_MAKEFILE TRUE)
 
-IF(WIN32)
-    INCLUDE (${CMAKE_SOURCE_DIR}/Source/WXDialog/bin/FindwxW.cmake)
-ELSE(WIN32)
-    INCLUDE (${CMAKE_SOURCE_DIR}/Source/WXDialog/bin/FindwxWin.cmake)
-    
-    # sync flags 
-    SET(WXWIDGETS_FOUND            ${WXWINDOWS_FOUND})
-    SET(WXWIDGETS_INCLUDE_DIR      ${WXWINDOWS_INCLUDE_DIR})
-    SET(WXWIDGETS_LINK_DIRECTORIES ${WXWINDOWS_LINK_DIRECTORIES})
-    SET(WXWIDGETS_LIBRARIES        ${WXWINDOWS_LIBRARIES})
-ENDIF(WIN32)
-
-# Old find script
+# in addition to wx std libs we need
+SET( WXWIDGETS_USE_LIBS html adv xml xrc )
+INCLUDE (${CMAKE_ROOT}/Modules/UsewxWidgets.cmake )
 
 ## Start using wx stuff when it is fully found and set
 IF(WXWIDGETS_FOUND)
@@ -58,24 +41,26 @@
             CommandLineInfo.cpp
             CommandLineInfo.h )
             
-    # include .rc when windows
-    
+    # include .rc when windows    
     IF(WIN32)
-        SET ( CMAKE_SRCS 
-                ${CMAKE_SRCS} 
-                CMakeSetup.rc )
+        SET ( CMAKE_SRCS ${CMAKE_SRCS}  CMakeSetup.rc )
     ENDIF(WIN32)
      
     INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/Source/WXDialog
-                        ${WXWIDGETS_INCLUDE_DIR})
+                        ${WXWIDGETS_INCLUDE_DIR} )
     LINK_DIRECTORIES( ${WXWIDGETS_LINK_DIRECTORIES} ${CMake_BINARY_DIR}/Source ${CMake_BINARY_DIR}/Source/kwsys )
+    
     IF(APPLE)
       ADD_EXECUTABLE(WXDialog MACOSX_BUNDLE  ${CMAKE_SRCS})
     ELSE(APPLE)
       ADD_EXECUTABLE(WXDialog WIN32  ${CMAKE_SRCS})
     ENDIF(APPLE)
     INSTALL_TARGETS(/bin WXDialog)
-    SET(CMAKE_CXX_FLAGS "${CMAKE_WX_CXX_FLAGS}")
+    
+    # not required on MSVS beause bound to _DEBUG, but other compiler may need it.
+    # However, the define prevents multiple build configurations in one build tree,
+    # e.g. MSVS supports Debug;Release
+    # TODO: shall we add the define or not - favor multi config or all compilers? (JW)
     SET(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D__WXDEBUG__ -DWXDEBUG=1")
                                      
     IF(LINUX)
@@ -84,13 +69,13 @@
     
     # if the checkbox view functionality is not desired,
     # exclude this part from the smple
-    SET(WXWIDGETS_LIBRARIES ${WXWIDGETS_LIBRARIES})
     TARGET_LINK_LIBRARIES(WXDialog ${WXWIDGETS_LIBRARIES} cmsys CMakeLib)
-        
-    # if UPX is found, make a target
-    
+
+
+    # if UPX is found, make a target    
     #INCLUDE (${CMAKE_SOURCE_DIR}/Source/WXDialog/bin/FindUPX.cmake)    
     #IF(UPX_FOUND)
     #END(UPX_FOUND)
-        
+
+
 ENDIF(WXWIDGETS_FOUND)
Index: Source/WXDialog/bin/FindUPX.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Source/WXDialog/bin/FindUPX.cmake,v
retrieving revision 1.1
diff -u -r1.1 FindUPX.cmake
--- Source/WXDialog/bin/FindUPX.cmake	30 Jun 2005 19:54:59 -0000	1.1
+++ Source/WXDialog/bin/FindUPX.cmake	4 Jul 2006 16:32:04 -0000
@@ -5,14 +5,11 @@
 # UPX_FOUND             Is set to 1 when upx is found
 
 FIND_PATH(UPX_PROGRAM_PATH upx.exe
-    "c:\Program Files\upx"
-    "d:\Program Files\upx"
-    "e:\Program Files\upx"
-    "f:\Program Files\upx"
-    "g:\Program Files\upx"
-    "h:\Program Files\upx"
+  ${UPX_DIR}
+  $ENV{UPX_DIR}
+  "$ENV{ProgramFiles}/upx"
   )
-  
+
 # when found, note this as target
 IF(UPX_PROGRAM_PATH)
   SET(UPX_FOUND 1)
Index: Source/WXDialog/bin/FindwxW.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Source/WXDialog/bin/FindwxW.cmake,v
retrieving revision 1.1
diff -u -r1.1 FindwxW.cmake
--- Source/WXDialog/bin/FindwxW.cmake	30 Jun 2005 19:54:59 -0000	1.1
+++ Source/WXDialog/bin/FindwxW.cmake	4 Jul 2006 16:30:08 -0000
@@ -1,3 +1,6 @@
+
+MESSAGE("${CMAKE_CURRENT_FILE} is deprecated, please use FindwxWidgets.cmake instead.")
+
 #
 # FindwxW.cmake
 # v1.01 2005-05-27
@@ -14,6 +17,7 @@
 #  WXWIDGETS_INCLUDE_DIR    = all include path of wxWindows
 #  WXWIDGETS_DEFINITIONS  = all flags of wxWindows
 
+
 # NOTE: This module REQUIRES that an environment variable named WXWIN
 # be set to the base wxWidgets installation directory.
 # Under Unix, you must also set and environment variable named WXWINCFG
Index: Source/WXDialog/bin/FindwxWin.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Source/WXDialog/bin/FindwxWin.cmake,v
retrieving revision 1.4
diff -u -r1.4 FindwxWin.cmake
--- Source/WXDialog/bin/FindwxWin.cmake	15 Jul 2005 15:38:43 -0000	1.4
+++ Source/WXDialog/bin/FindwxWin.cmake	4 Jul 2006 16:30:13 -0000
@@ -1,3 +1,8 @@
+
+
+MESSAGE("${CMAKE_CURRENT_FILE} is deprecated, please use FindwxWidgets.cmake instead.")
+
+
 ##---------------------------------------------------------------------------
 ## $RCSfile: FindwxWin.cmake,v $
 ## $Source: /cvsroot/CMake/CMake/Source/WXDialog/bin/FindwxWin.cmake,v $
Index: Source/WXDialog/bin/UsewxW.cmake
===================================================================
RCS file: /cvsroot/CMake/CMake/Source/WXDialog/bin/UsewxW.cmake,v
retrieving revision 1.1
diff -u -r1.1 UsewxW.cmake
--- Source/WXDialog/bin/UsewxW.cmake	30 Jun 2005 19:54:59 -0000	1.1
+++ Source/WXDialog/bin/UsewxW.cmake	4 Jul 2006 16:30:19 -0000
@@ -1,3 +1,7 @@
+
+MESSAGE("${CMAKE_CURRENT_FILE} is deprecated, please use FindwxWidgets.cmake instead.")
+
+
 #
 # UsewxW.cmake
 # v1.0 2005-05-27
Index: Tests/UseWX/CMakeLists.txt
===================================================================
RCS file: /cvsroot/CMake/CMake/Tests/UseWX/CMakeLists.txt,v
retrieving revision 1.2
diff -u -r1.2 CMakeLists.txt
--- Tests/UseWX/CMakeLists.txt	16 Oct 2003 23:16:19 -0000	1.2
+++ Tests/UseWX/CMakeLists.txt	4 Jul 2006 14:39:10 -0000
@@ -1,9 +1,9 @@
-PROJECT (UsewxWindows)
+PROJECT (UsewxWidgets)
 
-INCLUDE( ${CMAKE_ROOT}/Modules/Use_wxWindows.cmake)
+INCLUDE( ${CMAKE_ROOT}/Modules/UsewxWidgets.cmake)
 
 ADD_EXECUTABLE (UseWX WIN32 WX.cxx)
 
 #TODO: 
-#- dll linking is not working on WIN32, need to '-DWXUSINGDLL' to preprocessor
+#- dll linking is not working on WIN32, need to '-DWXUSINGDLL' to preprocessor  - fixed, JW
 
Index: Utilities/Release/config_Darwin
===================================================================
RCS file: /cvsroot/CMake/CMake/Utilities/Release/config_Darwin,v
retrieving revision 1.8
diff -u -r1.8 config_Darwin
--- Utilities/Release/config_Darwin	12 Jul 2005 21:22:41 -0000	1.8
+++ Utilities/Release/config_Darwin	4 Jul 2006 14:27:37 -0000
@@ -12,5 +12,6 @@
 CURSES_LIBRARY:FILEPATH=/Users/kitware/staticCurses/libncurses.a
 CMAKE_BUILD_WX_DIALOG:BOOL=ON
 CMAKE_WXWINDOWS_WXCONFIG_EXECUTABLE:FILEPATH=${WX_PREFIX}/wx-config
+CMAKE_WXWIDGETS_WXCONFIG_EXECUTABLE:FILEPATH=${WX_PREFIX}/wx-config
 EOF
 }