commit 286a534ea00bbee3198c6a23c4a99219748d777a
Author: Sam Thursfield <sam.thursfield@codethink.co.uk>
Date:   Tue Oct 20 23:53:49 2015 +0200

    FindPkgConfig: use absolute paths in _LIBRARIES variable
    
    This makes the pkg_check_modules() behaviour consistent with the normal
    CMake convention, where use of link_directories() is discouraged in
    favour of using absolute paths to system libraries.

diff --git a/Modules/FindPkgConfig.cmake b/Modules/FindPkgConfig.cmake
index e958deb..039d2b7 100644
--- a/Modules/FindPkgConfig.cmake
+++ b/Modules/FindPkgConfig.cmake
@@ -254,6 +254,19 @@ function(_pkg_set_cmake_pkgconfig_path _no_cmake_path _no_cmake_environment_path
   endif()
 endfunction()
 
+# Convert library names to absolute paths.
+function(_pkgconfig_find_libraries _output_var _prefix _library_names _library_dirs)
+    foreach(_libname ${_library_names})
+        # find_library stores its result in the cache, so we must pass a unique
+        # variable name for each library that we look for.
+        set(_library_path_var "${_prefix}_LIBRARY_${_libname}")
+
+        find_library(${_library_path_var} ${_libname} PATHS ${_library_dirs})
+        list(APPEND _library_paths "${${_library_path_var}}")
+    endforeach()
+    set(${_output_var} ${_library_paths} PARENT_SCOPE)
+endfunction()
+
 ###
 macro(_pkg_check_modules_internal _is_required _is_silent _no_cmake_path _no_cmake_environment_path _prefix)
   _pkgconfig_unset(${_prefix}_FOUND)
@@ -399,6 +412,9 @@ macro(_pkg_check_modules_internal _is_required _is_silent _no_cmake_path _no_cma
       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" INCLUDE_DIRS        "(^| )-I" --cflags-only-I )
       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" CFLAGS              ""        --cflags )
       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" CFLAGS_OTHER        ""        --cflags-only-other )
+
+      # convert library names in LIBRARIES to absolute paths.
+      _pkgconfig_find_libraries("${_prefix}_LIBRARIES" ${_prefix} "${${_prefix}_LIBRARIES}" "${${_prefix}_LIBRARY_DIRS}")
     endif()
 
     # Restore the environment variable

commit d8b04a31444d09430bdf971ad2f4fb286efe40d4
Author: Sam Thursfield <sam.thursfield@codethink.co.uk>
Date:   Tue Jan 12 18:51:12 2016 +0100

    Add PkgImportModule.cmake
    
    This allows you to create imported targets for any pkg-config module,
    without needing to write a separate CMake module for each one.
    
    This is an improvement on the current pkg_check_modules() function
    because the libraries will absolute paths rather than -l flags.
    Previously, you would need to consistently call link_libraries(), or
    call find_library() for each library returned from pkg_check_modules(),
    because otherwise building against a sysroot would break due to
    linking against libraries from the host instead of libraries from the
    sysroot.
    
    This also adds a support module AddObjectLibraryDependencies.
    
    Bug: https://cmake.org/Bug/view.php?id=15804

diff --git a/Modules/AddObjectLibraryDependencies.cmake b/Modules/AddObjectLibraryDependencies.cmake
new file mode 100644
index 0000000..568cffb
--- /dev/null
+++ b/Modules/AddObjectLibraryDependencies.cmake
@@ -0,0 +1,33 @@
+# ::
+#
+#    add_object_library_dependencies(<name> <dep1> [<dep2> ...])
+#
+# This is a workaround for <http://public.kitware.com/Bug/view.php?id=14778>.
+# It should be possible to delete this function and use target_link_libraries()
+# as normal once that is fixed.
+#
+function(add_object_library_dependencies object_library)
+    set(dependencies ${ARGN})
+    foreach(dependency ${dependencies})
+        if(NOT TARGET ${dependency})
+            message(FATAL_ERROR
+                "add_object_library_dependencies(): ${dependency} is not a "
+                "target.")
+        endif()
+
+        target_compile_definitions(
+            ${object_library} PUBLIC
+            $<TARGET_PROPERTY:${dependency},INTERFACE_COMPILE_DEFINITIONS>)
+        target_compile_options(
+            ${object_library} PUBLIC
+            $<TARGET_PROPERTY:${dependency},INTERFACE_COMPILE_OPTIONS>)
+        target_include_directories(
+            ${object_library} PUBLIC
+            $<TARGET_PROPERTY:${dependency},INTERFACE_INCLUDE_DIRECTORIES>)
+    endforeach()
+
+    get_target_property(object_library_link_libraries
+        ${object_library} LINK_LIBRARIES)
+    set_target_properties(${object_library} PROPERTIES
+        LINK_LIBRARIES "${dependencies};${object_library_link_libraries}")
+endfunction()
diff --git a/Modules/PkgImportModule.cmake b/Modules/PkgImportModule.cmake
new file mode 100644
index 0000000..adf4509
--- /dev/null
+++ b/Modules/PkgImportModule.cmake
@@ -0,0 +1,81 @@
+#.rst:
+# PkgImportModule
+# ---------------
+#
+# CMake commands to create imported targets from pkg-config modules.
+
+#=============================================================================
+# Copyright 2016 Lautsprecher Teufel GmbH
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+find_package(PkgConfig REQUIRED)
+
+# ::
+#
+#     pkg_import_module(<name> args)
+#
+# Creates an imported target named <name> from a pkg-config module. All
+# remaining arguments are passed through to pkg_check_module(). See the
+# documentation of the FindPkgConfig module for information.
+#
+# Example usage:
+#
+#   pkg_import_module(Archive::Archive REQUIRED libarchive>=3.0)
+#   pkg_import_module(Avahi::GObject REQUIRED avahi-gobject)
+#
+function(pkg_import_module name)
+    set(prefix _${name})
+    pkg_check_modules("${prefix}" ${ARGN})
+
+    _pkg_import_module_add_imported_target(
+        ${name}
+        "${${prefix}_CFLAGS_OTHER}"
+        "${${prefix}_INCLUDE_DIRS}"
+        "${${prefix}_LIBRARY_DIRS}"
+        "${${prefix}_LIBRARIES}"
+        )
+endfunction()
+
+function(_pkg_import_module_find_libraries output_var prefix library_names library_dirs)
+    foreach(libname ${library_names})
+        # find_library stores its result in the cache, so we must pass a unique
+        # variable name for each library that we look for.
+        set(library_path_var "${prefix}_LIBRARY_${libname}")
+        find_library(${library_path_var} ${libname} PATHS ${library_dirs})
+        list(APPEND library_paths "${${library_path_var}}")
+    endforeach()
+    set(${output_var} ${library_paths} PARENT_SCOPE)
+endfunction()
+
+function(_pkg_import_module_add_imported_target name compile_options include_dirs library_dirs libraries)
+    # FIXME: we should really detect whether it's SHARED or STATIC, instead of
+    # assuming SHARED. We can't just use UNKNOWN because nothing can link
+    # against it then.
+    add_library(${name} SHARED IMPORTED)
+
+    # We must pass in the absolute paths to the libraries, otherwise, when
+    # the library is installed in a non-standard prefix the linker won't be
+    # able to find the libraries. CMake doesn't provide a way for us to keep
+    # track of the library search path for a specific target, so we have to
+    # do it this way.
+    _pkg_import_module_find_libraries(libraries_full_paths
+        ${name} "${libraries}" "${library_dirs}")
+
+    list(GET libraries_full_paths 0 imported_location)
+
+    set_target_properties(${name} PROPERTIES
+        IMPORTED_LOCATION ${imported_location}
+        INTERFACE_COMPILE_OPTIONS "${compile_options}"
+        INTERFACE_INCLUDE_DIRECTORIES "${include_dirs}"
+        INTERFACE_LINK_LIBRARIES "${libraries_full_paths}"
+        )
+endfunction()