[Cmake-commits] CMake branch, next, updated. v2.8.6-2179-gc2e8c8c
Bill Hoffman
bill.hoffman at kitware.com
Fri Dec 9 18:05:44 EST 2011
This is an automated email from the git hooks/post-receive script. It was
generated because a ref change was pushed to the repository containing
the project "CMake".
The branch, next has been updated
via c2e8c8c11cdc75b31d2427c1fff3cb3af84361e4 (commit)
via 3b2d0c4ef3e8dca03b2b169c51c0a32d02462e9e (commit)
via f015a9b9ce5b37494b72a86c0ff4f66fecda52e4 (commit)
from a5b213a704b73e776b0f5a17d00e01cec1ebd224 (commit)
Those revisions listed above that are new to this repository have
not appeared on any other notification email; so we list those
revisions in full, below.
- Log -----------------------------------------------------------------
http://cmake.org/gitweb?p=cmake.git;a=commitdiff;h=c2e8c8c11cdc75b31d2427c1fff3cb3af84361e4
commit c2e8c8c11cdc75b31d2427c1fff3cb3af84361e4
Merge: a5b213a 3b2d0c4
Author: Bill Hoffman <bill.hoffman at kitware.com>
AuthorDate: Fri Dec 9 18:05:24 2011 -0500
Commit: CMake Topic Stage <kwrobot at kitware.com>
CommitDate: Fri Dec 9 18:05:24 2011 -0500
Merge topic 'cmake_add_fortran_subdirectory' into next
3b2d0c4 Add support for easy integration of MinGW gfortran and Visual Studio.
f015a9b Merge branch 'GNU-to-MS' into cmake_add_fortran_subdirectory
http://cmake.org/gitweb?p=cmake.git;a=commitdiff;h=3b2d0c4ef3e8dca03b2b169c51c0a32d02462e9e
commit 3b2d0c4ef3e8dca03b2b169c51c0a32d02462e9e
Author: Bill Hoffman <bill.hoffman at kitware.com>
AuthorDate: Fri Dec 9 18:04:19 2011 -0500
Commit: Bill Hoffman <bill.hoffman at kitware.com>
CommitDate: Fri Dec 9 18:04:19 2011 -0500
Add support for easy integration of MinGW gfortran and Visual Studio.
This patch adds a new module that allows for easy integration of
MinGW gfortran and the Visual Studio compiler. It is done in a
function called cmake_add_fortran_subdirectory. The patch also includes
a test for this feature.
diff --git a/Modules/CMakeAddFortranSubdirectory.cmake b/Modules/CMakeAddFortranSubdirectory.cmake
new file mode 100644
index 0000000..99f1ffe
--- /dev/null
+++ b/Modules/CMakeAddFortranSubdirectory.cmake
@@ -0,0 +1,162 @@
+# - Use MinGW gfortran from VS if a fortran compiler is not found.
+# The 'add_fortran_subdirectory' function adds a subdirectory
+# to a project that contains a fortran only sub-project. The module
+# will check the current compiler and see if it can support fortran.
+# If no fortran compiler is found and the compiler is MSVC, then
+# this module will find the MinGW gfortran. It will then use
+# an external project to build with the MinGW tools. It will also
+# create imported targets for the libraries created. This will only
+# work if the fortran code is built into a dll, so BUILD_SHARED_LIBS
+# is turned on in the project. In addition the GNUtoMS option is set
+# to on, so that the MS .lib files are created.
+# Usage is as follows:
+# cmake_add_fortran_subdirectory(
+# <subdir> # name of subdirectory
+# PROJECT <project_name> # project name in sbudir toplevel CMakeLists.txt
+# ARCHIVE_DIR <dir> # .lib location relative to root binary tree (lib)
+# RUNTIME_DIR <dir> # .dll location relative to root binary tree (bin)
+# LIBRARIES lib2 lib2 # names of libraries created and exported
+# LINK_LIBRARIES # link interface libraries for LIBRARIES
+# LINK_LIBS <lib1> <dep1> <dep2> ... <depN>
+# LINK_LIBS <lib2> <dep1> <dep2> ... <depN>
+# CMAKE_COMMAND_LINE # extra command line flags to pass to cmake
+# )
+#
+
+#=============================================================================
+# Copyright 2002-2009 Kitware, Inc.
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+# License text for the above reference.)
+
+
+set(_MS_MINGW_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR})
+include(CheckFortran)
+include(ExternalProject)
+include(CMakeParseArguments)
+
+function(_setup_mingw_config_and_build source_dir)
+ find_program(MINGW_GFORTRAN NAMES gfortran
+ HINTS
+ c:/MinGW/bin
+ "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\MinGW;InstallLocation]/bin" )
+ if(NOT MINGW_GFORTRAN)
+ message(FATAL_ERROR
+ "gfortran not found, please install MinGW with the gfortran option."
+ "Or set the cache variable MINGW_GFORTRAN to the full path. "
+ " This is required to build")
+ endif()
+ execute_process(COMMAND ${MINGW_GFORTRAN} -v ERROR_VARIABLE out)
+ if(NOT "${out}" MATCHES "Target:.*mingw32")
+ message(FATAL_ERROR "Non-MinGW gfortran found: ${MINGW_GFORTRAN}\n"
+ "output from -v [${out}]\n"
+ "set MINGW_GFORTRAN to the path to MinGW fortran.")
+ endif()
+ get_filename_component(MINGW_PATH ${MINGW_GFORTRAN} PATH)
+ file(TO_NATIVE_PATH "${MINGW_PATH}" MINGW_PATH)
+ string(REPLACE "\\" "\\\\" MINGW_PATH "${MINGW_PATH}")
+ configure_file(${_MS_MINGW_SOURCE_DIR}/config_mingw.cmake.in
+ ${CMAKE_CURRENT_BINARY_DIR}/config_mingw.cmake @ONLY)
+ configure_file(${_MS_MINGW_SOURCE_DIR}/build_mingw.cmake.in
+ ${CMAKE_CURRENT_BINARY_DIR}/build_mingw.cmake @ONLY)
+endfunction()
+
+function(_add_fortran_library_link_interface library depend_library)
+ set_target_properties(${library} PROPERTIES
+ IMPORTED_LINK_INTERFACE_LIBRARIES_NOCONFIG "${depend_library}")
+endfunction()
+
+
+function(cmake_add_fortran_subdirectory subdir)
+ # if we are not using MSVC without fortran support
+ # then just use the usual add_subdirectory to build
+ # the fortran library
+ if(NOT (MSVC AND (NOT CMAKE_Fortran_COMPILER)))
+ add_subdirectory(${subdir})
+ return()
+ endif()
+
+ # if we have MSVC without Intel fortran then setup
+ # external projects to build with mingw fortran
+
+ # Parse arguments to function
+ set(oneValueArgs PROJECT ARCHIVE_DIR RUNTIME_DIR)
+ set(multiValueArgs LIBRARIES LINK_LIBRARIES CMAKE_COMMAND_LINE)
+ cmake_parse_arguments(ARGS "" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+ set(source_dir "${CMAKE_CURRENT_SOURCE_DIR}/${subdir}")
+ set(project_name "${ARGS_PROJECT}")
+ set(library_dir "${ARGS_ARCHIVE_DIR}")
+ set(binary_dir "${ARGS_RUNTIME_DIR}")
+ set(libraries ${ARGS_LIBRARIES})
+ # use the same directory that add_subdirectory would have used
+ set(build_dir "${CMAKE_CURRENT_BINARY_DIR}/${subdir}")
+ # create build and configure wrapper scripts
+ _setup_mingw_config_and_build(${source_dir})
+ # create the external project
+ externalproject_add(${project_name}_build
+ SOURCE_DIR ${source_dir}
+ BINARY_DIR ${build_dir}
+ CONFIGURE_COMMAND ${CMAKE_COMMAND}
+ -P ${CMAKE_CURRENT_BINARY_DIR}/config_mingw.cmake
+ BUILD_COMMAND ${CMAKE_COMMAND}
+ -P ${CMAKE_CURRENT_BINARY_DIR}/build_mingw.cmake
+ INSTALL_COMMAND ""
+ )
+ # make the external project always run make with each build
+ externalproject_add_step(${project_name}_build forcebuild
+ COMMAND ${CMAKE_COMMAND}
+ -E remove
+ ${CMAKE_CURRENT_BUILD_DIR}/${project_name}-prefix/src/${project_name}-stamp/lapack-build
+ DEPENDEES configure
+ DEPENDERS build
+ ALWAYS 1
+ )
+ # create imported targets for all libraries
+ foreach(lib ${libraries})
+ add_library(${lib} SHARED IMPORTED)
+ set_property(TARGET ${lib} APPEND PROPERTY IMPORTED_CONFIGURATIONS NOCONFIG)
+ set_target_properties(${lib} PROPERTIES
+ IMPORTED_IMPLIB_NOCONFIG
+ "${build_dir}/${library_dir}/lib${lib}.lib"
+ IMPORTED_LOCATION_NOCONFIG
+ "${build_dir}/${binary_dir}/lib${lib}.dll"
+ )
+ add_dependencies(${lib} ${project_name}_build)
+ endforeach()
+
+ # now setup link libraries for targets
+ set(start FALSE)
+ set(target)
+ foreach(lib ${ARGS_LINK_LIBRARIES})
+ if("${lib}" STREQUAL "LINK_LIBS")
+ set(start TRUE)
+ else()
+ if(start)
+ if(DEFINED target)
+ # process current target and target_libs
+ _add_fortran_library_link_interface(${target} "${target_libs}")
+ # zero out target and target_libs
+ set(target)
+ set(target_libs)
+ endif()
+ # save the current target and set start to FALSE
+ set(target ${lib})
+ set(start FALSE)
+ else()
+ # append the lib to target_libs
+ list(APPEND target_libs "${lib}")
+ endif()
+ endif()
+ endforeach()
+ # process anything that is left in target and target_libs
+ if(DEFINED target)
+ _add_fortran_library_link_interface(${target} "${target_libs}")
+ endif()
+endfunction()
diff --git a/Tests/CheckFortran.cmake b/Modules/CheckFortran.cmake
similarity index 100%
rename from Tests/CheckFortran.cmake
rename to Modules/CheckFortran.cmake
diff --git a/Modules/build_mingw.cmake.in b/Modules/build_mingw.cmake.in
new file mode 100644
index 0000000..55b271a
--- /dev/null
+++ b/Modules/build_mingw.cmake.in
@@ -0,0 +1,2 @@
+set(ENV{PATH} "@MINGW_PATH@\;$ENV{PATH}")
+execute_process(COMMAND "@CMAKE_COMMAND@" --build . )
diff --git a/Modules/config_mingw.cmake.in b/Modules/config_mingw.cmake.in
new file mode 100644
index 0000000..96141da
--- /dev/null
+++ b/Modules/config_mingw.cmake.in
@@ -0,0 +1,8 @@
+set(ENV{PATH} "@MINGW_PATH@\;$ENV{PATH}")
+execute_process(
+ COMMAND "@CMAKE_COMMAND@" "-GMinGW Makefiles"
+ -DCMAKE_Fortran_COMPILER:PATH=@MINGW_GFORTRAN@
+ -DBUILD_SHARED_LIBS=ON
+ -DCMAKE_GNUtoMS=ON
+ @ARGS_CMAKE_COMMAND_LINE@
+ "@source_dir@")
diff --git a/Modules/external_mingw_project.cmake.in b/Modules/external_mingw_project.cmake.in
new file mode 100644
index 0000000..5db8a1e
--- /dev/null
+++ b/Modules/external_mingw_project.cmake.in
@@ -0,0 +1,54 @@
+include(ExternalProject)
+
+set(LAPACK_BUILD_DIR "${fortranc_BINARY_DIR}/lapack-build")
+find_program(MINGW_GFORTRAN gfortran
+ c:/MinGW/bin
+ "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\MinGW;InstallLocation]/bin")
+if(NOT MINGW_GFORTRAN)
+ message(FATAL_ERROR
+ "gfortran not found, please install MinGW with the gfortran option."
+ " This is required to build blas/lapack")
+endif()
+get_filename_component(MINGW_PATH ${MINGW_GFORTRAN} PATH)
+file(TO_NATIVE_PATH "${MINGW_PATH}" MINGW_PATH)
+string(REPLACE "\\" "\\\\" MINGW_PATH "${MINGW_PATH}")
+configure_file(${fortranc_SOURCE_DIR}/config_mingw.cmake.in
+ ${fortranc_BINARY_DIR}/config_mingw.cmake @ONLY)
+configure_file(${fortranc_SOURCE_DIR}/build_mingw.cmake.in
+ ${fortranc_BINARY_DIR}/build_mingw.cmake @ONLY)
+
+externalproject_add(LAPACK
+ SOURCE_DIR ${fortranc_SOURCE_DIR}/lapack
+ BINARY_DIR ${fortranc_BINARY_DIR}/lapack-build
+ CONFIGURE_COMMAND ${CMAKE_COMMAND}
+ -P ${fortranc_BINARY_DIR}/config_mingw.cmake
+ BUILD_COMMAND ${CMAKE_COMMAND}
+ -P ${fortranc_BINARY_DIR}/build_mingw.cmake
+ INSTALL_COMMAND ""
+)
+
+externalproject_add_step(LAPACK forcebuild
+ COMMAND ${CMAKE_COMMAND}
+ -E remove ${CMAKE_CURRENT_BUILD_DIR}/lapack-prefix/src/lapack-stamp/lapack-build
+ DEPENDEES configure
+ DEPENDERS build
+ ALWAYS 1
+)
+
+add_library(blas SHARED IMPORTED)
+add_library(lapack SHARED IMPORTED)
+# Import target "blas" for configuration ""
+set_property(TARGET blas APPEND PROPERTY IMPORTED_CONFIGURATIONS NOCONFIG)
+set_target_properties(blas PROPERTIES
+ IMPORTED_IMPLIB_NOCONFIG "${LAPACK_BUILD_DIR}/lib/libblas.lib"
+ IMPORTED_LOCATION_NOCONFIG "${LAPACK_BUILD_DIR}/bin/libblas.dll"
+ )
+
+# Import target "lapack" for configuration ""
+set_property(TARGET lapack APPEND PROPERTY IMPORTED_CONFIGURATIONS NOCONFIG)
+set_target_properties(lapack PROPERTIES
+ IMPORTED_IMPLIB_NOCONFIG "${LAPACK_BUILD_DIR}/lib/liblapack.lib"
+ IMPORTED_LINK_INTERFACE_LIBRARIES_NOCONFIG "blas"
+ IMPORTED_LOCATION_NOCONFIG "${LAPACK_BUILD_DIR}/bin/liblapack.dll"
+ )
+add_dependencies(lapack LAPACK)
diff --git a/Tests/CMakeLists.txt b/Tests/CMakeLists.txt
index 1851f7a..83a2312 100644
--- a/Tests/CMakeLists.txt
+++ b/Tests/CMakeLists.txt
@@ -16,7 +16,7 @@ MACRO(ADD_TEST_MACRO NAME COMMAND)
LIST(APPEND TEST_BUILD_DIRS "${CMake_BINARY_DIR}/Tests/${dir}")
ENDMACRO(ADD_TEST_MACRO)
-INCLUDE(${CMAKE_CURRENT_SOURCE_DIR}/CheckFortran.cmake)
+INCLUDE(${CMake_SOURCE_DIR}/Modules/CheckFortran.cmake)
# Fake a user home directory to avoid polluting the real one.
IF(DEFINED ENV{HOME} AND NOT CTEST_NO_TEST_HOME)
@@ -162,6 +162,15 @@ IF(BUILD_TESTING)
IF(CMAKE_Fortran_COMPILER)
ADD_TEST_MACRO(FortranOnly FortranOnly)
ENDIF()
+ # test Visual Studio GNU Fortran mixing with cmake_add_fortran_subdirectory
+ # run this project if we have a working fortran compiler or
+ # the test is enabled with CMAKE_TEST_CMAKE_ADD_FORTRAN cache variable.
+ # If you enable the test, CMake should find the MinGW fortran install,
+ # or in some cases you might need to set the PATH so that cmake can find
+ # the gfortran from mingw.
+ IF(CMAKE_Fortran_COMPILER OR CMAKE_TEST_CMAKE_ADD_FORTRAN)
+ ADD_TEST_MACRO(VSGNUFortran ${CMAKE_COMMAND} -P runtest.cmake)
+ ENDIF()
ADD_TEST_MACRO(COnly COnly)
ADD_TEST_MACRO(CxxOnly CxxOnly)
ADD_TEST_MACRO(IPO COnly/COnly)
diff --git a/Tests/VSGNUFortran/CMakeLists.txt b/Tests/VSGNUFortran/CMakeLists.txt
new file mode 100644
index 0000000..973fe5c
--- /dev/null
+++ b/Tests/VSGNUFortran/CMakeLists.txt
@@ -0,0 +1,26 @@
+cmake_minimum_required(VERSION 2.8)
+project(VSGNUFortran)
+
+set(EXECUTABLE_OUTPUT_PATH ${VSGNUFortran_BINARY_DIR}/bin)
+set(LIBRARY_OUTPUT_PATH ${VSGNUFortran_BINARY_DIR}/bin)
+
+include(CMakeAddFortranSubdirectory)
+# add the lapack subdirectory as a fortran project
+# the subdir is lapack, the project is LAPACK
+cmake_add_fortran_subdirectory(fortran
+ PROJECT FortranHello # project name in toplevel CMakeLists.txt
+ ARCHIVE_DIR ../bin # .lib location relative to root binary tree
+ RUNTIME_DIR ../bin # .dll location relative to root binary tree
+ LIBRARIES hello world # target libraries created
+ CMAKE_COMMAND_LINE -DEXECUTABLE_OUTPUT_PATH=../bin
+ -DLIBRARY_OUTPUT_PATH=../bin
+ LINK_LIBRARIES # link interface libraries
+ LINK_LIBS hello world # hello needs world to link
+ )
+
+include_directories(${VSGNUFortran_BINARY_DIR}/fortran)
+add_subdirectory(c_code)
+# use a cmake script to run the executable so that PATH
+# can be set with the MinGW/bin in it, and the fortran
+# runtime libraries can be found.
+configure_file(runtest.cmake.in runtest.cmake @ONLY)
diff --git a/Tests/VSGNUFortran/c_code/CMakeLists.txt b/Tests/VSGNUFortran/c_code/CMakeLists.txt
new file mode 100644
index 0000000..95c641e
--- /dev/null
+++ b/Tests/VSGNUFortran/c_code/CMakeLists.txt
@@ -0,0 +1,10 @@
+add_executable(c_using_fortran main.c)
+# force the executable to be put out of Debug/Release dir
+# because gmake build of fortran will not be in a config
+# directory.
+if(CMAKE_CONFIGURATION_TYPES)
+ set_target_properties(c_using_fortran PROPERTIES
+ OUTPUT_NAME ../c_using_fortran)
+endif()
+
+target_link_libraries(c_using_fortran hello)
diff --git a/Tests/VSGNUFortran/c_code/main.c b/Tests/VSGNUFortran/c_code/main.c
new file mode 100644
index 0000000..391bf26
--- /dev/null
+++ b/Tests/VSGNUFortran/c_code/main.c
@@ -0,0 +1,7 @@
+#include <HelloWorldFCMangle.h> // created by FortranCInterface
+extern void FC_hello(void);
+int main()
+{
+ FC_hello();
+ return 0;
+}
diff --git a/Tests/VSGNUFortran/fortran/CMakeLists.txt b/Tests/VSGNUFortran/fortran/CMakeLists.txt
new file mode 100644
index 0000000..ff22993
--- /dev/null
+++ b/Tests/VSGNUFortran/fortran/CMakeLists.txt
@@ -0,0 +1,12 @@
+cmake_minimum_required(VERSION 2.8)
+project(FortranHello Fortran C)
+
+include(FortranCInterface)
+FortranCInterface_HEADER(HelloWorldFCMangle.h
+ MACRO_NAMESPACE "FC_"
+ SYMBOL_NAMESPACE "FC_"
+ SYMBOLS hello world)
+
+add_library(hello SHARED hello.f)
+add_library(world SHARED world.f)
+target_link_libraries(hello world)
diff --git a/Tests/VSGNUFortran/fortran/hello.f b/Tests/VSGNUFortran/fortran/hello.f
new file mode 100644
index 0000000..291a43c
--- /dev/null
+++ b/Tests/VSGNUFortran/fortran/hello.f
@@ -0,0 +1,6 @@
+ SUBROUTINE HELLO
+
+ PRINT *, 'Hello'
+ CALL WORLD
+
+ END
diff --git a/Tests/VSGNUFortran/fortran/world.f b/Tests/VSGNUFortran/fortran/world.f
new file mode 100644
index 0000000..deae3fa
--- /dev/null
+++ b/Tests/VSGNUFortran/fortran/world.f
@@ -0,0 +1,5 @@
+ SUBROUTINE WORLD
+
+ PRINT *, 'World!'
+
+ END
diff --git a/Tests/VSGNUFortran/runtest.cmake.in b/Tests/VSGNUFortran/runtest.cmake.in
new file mode 100644
index 0000000..987207b
--- /dev/null
+++ b/Tests/VSGNUFortran/runtest.cmake.in
@@ -0,0 +1,23 @@
+get_filename_component(MINGW_PATH "@MINGW_GFORTRAN@" PATH)
+if(NOT EXISTS "${MINGW_PATH}")
+ set(test_exe
+ "@VSGNUFortran_BINARY_DIR@/bin/c_using_fortran at CMAKE_EXECUTABLE_SUFFIX@")
+ message("run: ${test_exe}")
+ execute_process(COMMAND "${test_exe}"
+ RESULT_VARIABLE res)
+ if(NOT "${res}" EQUAL 0)
+ message(FATAL_ERROR "${test_exe} returned a non 0 value")
+ endif()
+ return()
+endif()
+file(TO_NATIVE_PATH "${MINGW_PATH}" MINGW_PATH)
+string(REPLACE "\\" "\\\\" MINGW_PATH "${MINGW_PATH}")
+message("${MINGW_PATH}")
+set(test_exe "@VSGNUFortran_BINARY_DIR@/bin/c_using_fortran.exe")
+set(ENV{PATH} "${MINGW_PATH}";$ENV{PATH})
+message("run ${test_exe}")
+execute_process(COMMAND "${test_exe}"
+ RESULT_VARIABLE res)
+if(NOT "${res}" EQUAL 0)
+ message(FATAL_ERROR "${test_exe} returned a non 0 value")
+endif()
http://cmake.org/gitweb?p=cmake.git;a=commitdiff;h=f015a9b9ce5b37494b72a86c0ff4f66fecda52e4
commit f015a9b9ce5b37494b72a86c0ff4f66fecda52e4
Merge: 6fb2a38 c213eb9
Author: Bill Hoffman <bill.hoffman at kitware.com>
AuthorDate: Thu Dec 8 13:42:13 2011 -0500
Commit: Bill Hoffman <bill.hoffman at kitware.com>
CommitDate: Thu Dec 8 13:42:13 2011 -0500
Merge branch 'GNU-to-MS' into cmake_add_fortran_subdirectory
-----------------------------------------------------------------------
Summary of changes:
Modules/CMakeAddFortranSubdirectory.cmake | 162 +++++++++++++++++++++++
{Tests => Modules}/CheckFortran.cmake | 0
Modules/build_mingw.cmake.in | 2 +
Modules/config_mingw.cmake.in | 8 +
Modules/external_mingw_project.cmake.in | 54 ++++++++
Tests/CMakeLists.txt | 11 ++-
Tests/VSGNUFortran/CMakeLists.txt | 26 ++++
Tests/VSGNUFortran/c_code/CMakeLists.txt | 10 ++
Tests/VSGNUFortran/c_code/main.c | 7 +
Tests/VSGNUFortran/fortran/CMakeLists.txt | 12 ++
Tests/{Fortran => VSGNUFortran/fortran}/hello.f | 2 +-
Tests/{Fortran => VSGNUFortran/fortran}/world.f | 1 -
Tests/VSGNUFortran/runtest.cmake.in | 23 ++++
13 files changed, 315 insertions(+), 3 deletions(-)
create mode 100644 Modules/CMakeAddFortranSubdirectory.cmake
rename {Tests => Modules}/CheckFortran.cmake (100%)
create mode 100644 Modules/build_mingw.cmake.in
create mode 100644 Modules/config_mingw.cmake.in
create mode 100644 Modules/external_mingw_project.cmake.in
create mode 100644 Tests/VSGNUFortran/CMakeLists.txt
create mode 100644 Tests/VSGNUFortran/c_code/CMakeLists.txt
create mode 100644 Tests/VSGNUFortran/c_code/main.c
create mode 100644 Tests/VSGNUFortran/fortran/CMakeLists.txt
copy Tests/{Fortran => VSGNUFortran/fortran}/hello.f (78%)
copy Tests/{Fortran => VSGNUFortran/fortran}/world.f (97%)
create mode 100644 Tests/VSGNUFortran/runtest.cmake.in
hooks/post-receive
--
CMake
More information about the Cmake-commits
mailing list