# - Adjust the library variables for a given library.
#
# This macro takes a library base name as an argument, and will choose good
# values for basename_LIBRARY, basename_LIBRARY_DEBUG, and
# basename__LIBRARY_RELEASE depending on what has been set.  If only
# basename_RELEASE was found, basename, basename_DEBUG, and basename_RELEASE
# will be set to the release value.  The same is true if only basename_DEBUG was
# found, but all values will take the value of basename_DEBUG.  If no build type
# has been set or the generator in use does not support configuration types,
# then only the release value will be used.
#
# This macro was taken from the FindQt4.cmake module.

# Utility macro to check if one variable exists while another doesn't, and set
# one that doesn't exist to the one that exists.
macro( set_library_name basename GOOD BAD )
    if( ${basename}_LIBRARY_${GOOD} AND NOT ${basename}_LIBRARY_${BAD} )
        set( ${basename}_LIBRARY_${BAD} ${${basename}_LIBRARY_${GOOD}} )
        set( ${basename}_LIBRARY ${${basename}_LIBRARY_${GOOD}} )
    endif( ${basename}_LIBRARY_${GOOD} AND NOT ${basename}_LIBRARY_${BAD} )
endmacro()

macro( adjust_library_variables basename )
    # if only the release version was found, set the debug to be the release
    # version.
    set_library_name( ${basename} RELEASE DEBUG )
    # if only the debug version was found, set the release value to be the
    # debug value.
    set_library_name( ${basename} DEBUG RELEASE )
    if (${basename}_LIBRARY_DEBUG AND ${basename}_LIBRARY_RELEASE )
        # if the generator supports configuration types or CMAKE_BUILD_TYPE
        # is set, then set optimized and debug options.
        if( CMAKE_CONFIGURATION_TYPES OR CMAKE_BUILD_TYPE )
            set( ${basename}_LIBRARY 
                optimized ${${basename}_LIBRARY_RELEASE}
                debug ${${basename}_LIBRARY_DEBUG} )
        else( CMAKE_CONFIGURATION_TYPES OR CMAKE_BUILD_TYPE )
            # If there are no configuration types or build type, just use
            # the release version
            set( ${basename}_LIBRARY ${${basename}_LIBRARY_RELEASE} )
        endif( CMAKE_CONFIGURATION_TYPES OR CMAKE_BUILD_TYPE )
    endif( ${basename}_LIBRARY_DEBUG AND ${basename}_LIBRARY_RELEASE )

    set( ${basename}_LIBRARY ${${basename}_LIBRARY} CACHE FILEPATH 
        "The ${basename} library" )

    if( ${basename}_LIBRARY )
        set( ${basename}_FOUND TRUE )
    endif( ${basename}_LIBRARY )

    mark_as_advanced( ${basename}_LIBRARY 
        ${basename}_LIBRARY_RELEASE
        ${basename}_LIBRARY_DEBUG
    )
endmacro( adjust_library_variables )